Call FFish Function From Flash Directly

[ScreenSaver]

Hi everybody ..

I am asking how can I call a FFish Function from actionscript using import SWFKit .* ?


I tried to do like that :

import SWFKit .*
ShowForm();

And the ShowForm is a function written in the Swfkit script editor .


so please tell me what's the mistake and how can I call the function from flash 8 ?

[SWFKit]

To call a global ffish script from actionscript, please use the external interface:

ExternalInterface.call(functionName, param0, param1, ..., paramN);

E.g.

ExternalInterface.call("ShowForm");

To call an actionscript function from within ffish script, please first use the ExternalInterface.addCallback in actionscript to export the function, second in ffish script use the Application.registerASMethods method to register the function, and then you can call it as if a ffish script function. E.g. in actionscript:

function add(a, b)
{
    return a+b;
}

ExternalInterface.addCallback("AS_add", null, add);

in ffish script

Application.registerASMethods("AS_add");
AS_add(1, 2);

[ScreenSaver]

thank you very very much

And I have an other question :

How can I read and write to file using DataFile method directly from flash ??

[SWFKit]

Yes, but the DataFile object is used to save and load ffish script variables. Therefore it is unnecessary to call it in actionscript, and we do not provide an actionscript wrapper class for the DataFile object. Do you mean to find out a way to save and load actionscript variables by using swfkit express?

[ScreenSaver]

Yes please .

[SWFKit]

You can use the following class to save and load actionscript variables

import SWFKit.*;
import flash.external.*;

class SavedObject {
static private var initCount:Number = 0;
private var objSaved:Object;
private var fileName:String;

public function SavedObject(fileName:String) {
this.fileName = Global.getAppDir() + fileName;
init();
}

private function init() {
if (SavedObject.initCount == 0)
{
SavedObject.initCount++;
Global.eval("__asVars = new Object;" +
"function __setAsVars(value) {" +
"__asVars = value;" +
"}" +
"function __getAsVars() {" +
"return __asVars;" +
"}");
}
}

public function load() {
ExternalInterface.call("ffish_call", "DataFile", "load", this.fileName);
this.objSaved = ExternalInterface.call("__getAsVars");
}

public function save() {
ExternalInterface.call("__setAsVars", this.objSaved);
ExternalInterface.call("ffish_call", "DataFile", "remove", 
   this.fileName);
ExternalInterface.call("ffish_call", "DataFile", "save", 
   this.fileName, "__asVars");
}

public function get data() {
return this.objSaved;
}
}

[SWFKit]

For example, loading variables

import SWFKit.*;

var so = new SavedObject("1.dat");
so.load();

Dialogs.msgBox(so.data.score);
Dialogs.msgBox(so.data.userName);
Dialogs.msgBox(so.data.arr);

where "1.dat" is the name of the data file, without path name. The data files will be saved into the same folder as the executable files.

[SWFKit]

Saving variables

so.data.score = 100;
so.data.userName = "Hello";
so.data.arr = new Array();
so.data.arr[0] = true;
so.data.arr[1] = 100.1;
so.save();

Note: the data property of the SavedObject is read-only, so you can only change its properties and cannot change itself.

[ScreenSaver]

That's what I want :-*

I will test it

Thank you very much .

[dmitri_lbk]

Hi everybody!
I use this nice class "SavedObject" and it work correct allways. It save and load variables without problems. But when i'm replacing
ExternalInterface.call("ffish_call", "DataFile", "save", "this.fileName", "__asVars");
with
ExternalInterface.call("ffish_call", "DataFile", "saveAndEnc", "this.fileName", "__asVars"); it continue working, but only in Flash "commands -> swfkit_previewapp"

And standalone EXE file does't want save anything.
Can you help me to fix it?

p.s.
sorry for awful english :)